home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 22 / CU Amiga Magazine's Super CD-ROM 22 (1998)(EMAP Images)(GB)[!][issue 1998-05].iso / PowerPC / Datatypes / akJFIF / Install < prev   
Encoding:
Text File  |  1998-03-06  |  4.1 KB  |  121 lines
  1. ;$VER: akJFIF_Installer 43.160 (4.3.1998) #DOS © Msi Software
  2.  
  3. FAILAT 21
  4.  
  5. ;Check OS version!
  6. c/akT OS 39
  7. IF WARN
  8.    ECHO "You need OS 3.0 or later!"
  9.    ASK "Press return!"
  10.    QUIT
  11. ENDIF
  12.  
  13. ;Display old and new dt version etc!
  14. c/akT >ENV:akver VER classes/Datatypes/akJFIF.datatype
  15. c/akT >ENV:akverold VER Sys:Classes/Datatypes/akJFIF.datatype
  16. IF NOT WARN
  17.    C:RequestChoice >NIL: "Andreas Ralph Kleinert presents:" "$akver" "Install/Update"
  18. ELSE
  19.    C:RequestChoice >NIL: "Andreas Ralph Kleinert presents:" "$akver*N(old: $akverold)" "Install/Update"
  20. ENDIF
  21. UNSETENV akver
  22. UNSETENV akverold
  23.  
  24. ;Create dt prefs drawer if not found!
  25. IF NOT EXISTS SYS:Prefs/DataTypes
  26.    C:Makedir >NIL: SYS:Prefs/DataTypes
  27.    C:Copy >NIL: prefs/datatypes.info SYS:Prefs/DataTypes.info CLONE
  28. ENDIF
  29.  
  30. ;Move any dtprefs to sys:prefs/datatypes!
  31. IF EXISTS sys:prefs/akJFIFprefs
  32.    C:Rename >NIL: sys:prefs/akJFIFprefs#? sys:prefs/datatypes
  33. ENDIF
  34.  
  35. ;Create ENV:Datatypes if not found!
  36. IF NOT EXISTS ENV:Datatypes
  37.    C:Makedir >NIL: ENV:Datatypes ENVARC:Datatypes
  38. ENDIF
  39.  
  40. ;Install dtprefs if not found or current one is old!
  41. c/akT CHK prefs/datatypes/akJFIFPrefs SYS:prefs/datatypes/akJFIFPrefs
  42. IF WARN
  43.    C:Copy >NIL: prefs/datatypes/akJFIFPrefs SYS:prefs/datatypes CLONE
  44.    IF NOT EXISTS SYS:prefs/datatypes/akJFIFPrefs.info
  45.       C:Copy >NIL: prefs/datatypes/akJFIFPrefs.info SYS:prefs/datatypes CLONE
  46.    ENDIF
  47. ENDIF
  48.  
  49. ;Install gui if not found or current one is old!
  50. c/akT CHK prefs/datatypes/akJFIFPrefs_gui.wizard SYS:prefs/datatypes/akJFIFPrefs_gui.wizard
  51. IF WARN
  52.    C:Copy >NIL: prefs/datatypes/akJFIFPrefs_gui.wizard SYS:prefs/datatypes CLONE
  53. ENDIF
  54.  
  55. ;Install correct dt!
  56. c/akT CHK classes/datatypes/akJFIF.datatype SYS:classes/datatypes/akJFIF.datatype
  57. IF WARN
  58.    c/akT CPU 060
  59.    IF NOT WARN
  60.       C:Copy >NIL: classes/datatypes/akJFIF.datatype.060 SYS:Classes/datatypes/akJFIF.datatype CLONE
  61.    ELSE
  62.       c/akT CPU 040
  63.       IF NOT WARN
  64.          C:Copy >NIL: classes/datatypes/akJFIF.datatype.040 SYS:Classes/datatypes/akJFIF.datatype CLONE
  65.       ELSE
  66.          c/akT CPU 030
  67.          IF NOT WARN
  68.             C:Copy >NIL: classes/datatypes/akJFIF.datatype.030 SYS:Classes/datatypes/akJFIF.datatype CLONE
  69.          ELSE
  70.             c/akT CPU 020
  71.             IF NOT WARN
  72.                C:Copy >NIL: classes/datatypes/akJFIF.datatype.030 SYS:Classes/datatypes/akJFIF.datatype CLONE
  73.             ELSE
  74.                C:Copy >NIL: classes/datatypes/akJFIF.datatype SYS:Classes/datatypes/akJFIF.datatype CLONE
  75.             ENDIF
  76.          ENDIF
  77.       ENDIF
  78.    ENDIF
  79.  
  80.    ;Move any old dt headers to storage!
  81.    Rename >NIL: SYS:Devs/Datatypes/#?JFIF SYS:Storage/Datatypes/
  82.    Rename >NIL: SYS:Devs/Datatypes/#?JPEG#? SYS:Storage/Datatypes/
  83.    Rename >NIL: SYS:Devs/Datatypes/JPG#? SYS:Storage/Datatypes/
  84.  
  85.    ;Install new dt header!
  86.    C:Copy >NIL: devs/datatypes/JFIF DEVS:DataTypes
  87.    IF NOT EXISTS DEVS:DataTypes/JFIF.info
  88.       C:Copy >NIL: devs/datatypes/JFIF.info DEVS:DataTypes
  89.    ENDIF
  90.  
  91.    ;If VMEM assign not found, assign it and add to user-startup!
  92.    c/akT ASN vmem
  93.    IF WARN
  94.       C:RequestChoice >NIL: "ak Installer" "The VMEM: assign was not found!*NIt is needed by this datatype,*Nto be used as temporary directory." "Assign"
  95.       C:RequestFile >ENV:akvmem "SYS:" TITLE="Please select temporary dir:" SAVEMODE DRAWERSONLY NOICONS
  96.       ECHO >>S:User-Startup "*N;BEGIN VMEM"
  97.       ECHO >>S:User-Startup "Assign >NIL: VMEM: " NOLINE
  98.       ECHO >>S:User-Startup $akvmem
  99.       ECHO >>S:User-Startup ";END VMEM"
  100.       C:Assign >NIL: VMEM: $akvmem
  101.       UNSETENV akvmem
  102.    ENDIF
  103.  
  104.    ;Change dir to docs!
  105.    CD Docs
  106.  
  107.    ;Show guide and start dtprefs!
  108.    Run >NIL: MultiView akJFIF.guide
  109.    Run >NIL: /Prefs/DataTypes/akJFIFPrefs
  110.  
  111.    ;Install completed message!
  112.    C:RequestChoice >NIL: "ak Installer" "Install completed!*NPlease reboot the system,*Nto use the new datatype!*N*NIf this is the first time you install,*Nyou do not need to reboot!" "Ok"
  113.    C:AddDataTypes >NIL: REFRESH
  114. ELSE
  115.    ;Install not needed message!
  116.    C:RequestChoice >NIL: "ak Installer" "Install not needed!*NYou have the same or a higher version!" "Ok"
  117. ENDIF
  118.  
  119. ;Clean up memory/free resources!
  120. C:Avail >NIL: FLUSH
  121.